GradleUtils/build.gradle.kts

/*
 * Copyright 2021 dorkbox, llc
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
import dorkbox.gradle.kotlin
import java.time.Instant

gradle.startParameter.showStacktrace = ShowStacktrace.ALWAYS   // always show the stacktrace!
gradle.startParameter.warningMode = WarningMode.All

plugins {
    java
    `java-gradle-plugin`

    id("com.gradle.plugin-publish") version "0.14.0"

    id("com.dorkbox.Licensing") version "2.9.2"
    id("com.dorkbox.VersionUpdate") version "2.4"
    id("com.dorkbox.GradleUtils") version "2.9"

    kotlin("jvm") version "1.5.21"
}

object Extras {
    // set for the project
    const val description = "Gradle Plugin to manage various Gradle tasks, such as updating gradle and dependencies"
    const val group = "com.dorkbox"
    const val version = "2.10"

    // set as project.ext
    const val name = "Gradle Utils"
    const val id = "GradleUtils"
    const val vendor = "Dorkbox LLC"
    const val url = "https://git.dorkbox.com/dorkbox/GradleUtils"

    val buildDate = Instant.now().toString()
}

///////////////////////////////
/////  assign 'Extras'
///////////////////////////////
GradleUtils.load("$projectDir/../../gradle.properties", Extras)
GradleUtils.fixIntellijPaths()
GradleUtils.defaultResolutionStrategy()
GradleUtils.compileConfiguration(JavaVersion.VERSION_1_8)

licensing {
    license(License.APACHE_2) {
        description(Extras.description)
        author(Extras.vendor)
        url(Extras.url)
    }
}

sourceSets {
    main {
        java {
            setSrcDirs(listOf("src"))

            // want to include kotlin files for the source. 'setSrcDirs' resets includes...
            include("**/*.kt")
        }
    }
}
//
//fun hasKotlin(project: Project, debug: Boolean = false): Boolean {
//    try {
//        // check if plugin is available
//        project.plugins.findPlugin("org.jetbrains.kotlin.jvm") ?: return false
//
//        if (debug) println("\tHas kotlin plugin")
//
//        // this will check if the task exists, and throw an exception if it does not or return false
//        project.tasks.named("compileKotlin", org.jetbrains.kotlin.gradle.tasks.KotlinCompile::class.java).orNull ?: return false
//
//        if (debug) println("\tHas compile kotlin task")
//
//        // check to see if we have any kotlin file
//        val sourceSets = project.extensions.getByName("sourceSets") as SourceSetContainer
//        val main = sourceSets.getByName("main")
//
//        project.extensions.getByType(org.jetbrains.kotlin.gradle.dsl.KotlinJvmProjectExtension::class.java).sourceSets.getByName("main").kotlin.apply {
//            println("DIRS: ${this.srcDirs}")
//        }
//
//        if (debug) {
//            println("ASDASDSD")
//            println("\tmain dirs: ${main.java.srcDirs}")
//            println("\tkotlin dirs: ${main.kotlin.srcDirs}")
//
//            project.buildFile.parentFile.walkTopDown().filter { it.extension == "kt" }.forEach {
//                println("\t\t$it")
//            }
//        }
//
//        val files = main.java.srcDirs + main.kotlin.srcDirs
//        files.forEach { srcDir ->
//            val kotlinFile = srcDir.walkTopDown().find { it.extension == "kt" }
//            if (kotlinFile?.exists() == true) {
//                if (debug) println("\t Has kotlin file: $kotlinFile")
//                return true
//            }
//        }
//    } catch (e: Exception) {
//        if (debug) e.printStackTrace()
//    }
//
//    return false
//}
//
//println("HASKOT = ${hasKotlin(project, true)}")

repositories {
    mavenLocal()
    mavenCentral()
    gradlePluginPortal()
}

dependencies {
    // compile only, so we don't force kotlin/dsl version info into dependencies

    // the kotlin version is taken from the plugin, so it is not necessary to set it here
    compileOnly("org.jetbrains.kotlin:kotlin-gradle-plugin")

    // for parsing JSON
    implementation("org.json:json:20210307")

    // for parsing version information from maven
    implementation("com.dorkbox:Version:2.4")
}

tasks.jar.get().apply {
    manifest {
        // https://docs.oracle.com/javase/tutorial/deployment/jar/packageman.html
        attributes["Name"] = Extras.name

        attributes["Specification-Title"] = Extras.name
        attributes["Specification-Version"] = Extras.version
        attributes["Specification-Vendor"] = Extras.vendor

        attributes["Implementation-Title"] = "${Extras.group}.${Extras.id}"
        attributes["Implementation-Version"] = Extras.buildDate
        attributes["Implementation-Vendor"] = Extras.vendor
    }
}


/////////////////////////////////
////////    Plugin Publishing + Release
/////////////////////////////////
gradlePlugin {
    plugins {
        create("GradleUtils") {
            id = "${Extras.group}.${Extras.id}"
            implementationClass = "dorkbox.gradle.GradleUtils"
        }
    }
}

pluginBundle {
    website = Extras.url
    vcsUrl = Extras.url

    (plugins) {
        "GradleUtils" {
            id = "${Extras.group}.${Extras.id}"
            displayName = Extras.name
            description = Extras.description
            tags = listOf("gradle", "update", "dependencies", "dependency management")
            version = Extras.version
        }
    }
}